fenster im vordergrund bei vb6 - rückgängig

SeekeR

hmm ich hab so das gefühl ich bin der einer der wenigen die hier im forum posten, aber ich hätte wiedermal eine frage. ich hoff ihr verweist mich nicht wieder auf vbarchiv, wäre schade wenn dieses forum ausstirbt. also zu meinem problem:

ich hab im internet einen sehr schönen code für vb6 gefunden, den ich in ein modul reinkopiert habe:

Code

Option Explicit


' alle benötigten API-Deklarationen
Private Declare Function SetWindowPos Lib "user32" _
  (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal x As Long, ByVal y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long

Private Declare Function GetWindowLong Lib "user32" _
  Alias "GetWindowLongA" (ByVal hwnd As Long, _
  ByVal nIndex As Long) As Long


Private Declare Function SetWindowLong Lib "user32" _
  Alias "SetWindowLongA" (ByVal hwnd As Long, _
  ByVal nIndex As Long, ByVal dwNewLong As Long) As Long


Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOZORDER = &H4
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_REFRESH = SWP_NOZORDER Or _
  SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE Or _
  SWP_FRAMECHANGED


Private Const GWL_STYLE = (-16)


Private Const WS_MAXIMIZEBOX = &H10000
Private Const WS_MINIMIZEBOX = &H20000


Private Const HWND_TOPMOST = -1


' Minimieren/Maximieren Button einer Form anzeigen
Public Sub MinMaxButton(Form As Form)
  Dim Style As Long


  With Form
    Style = GetWindowLong(.hwnd, GWL_STYLE)
    Style = Style Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX
    SetWindowLong .hwnd, GWL_STYLE, Style
    SetWindowPos .hwnd, 0, 0, 0, 0, 0, SWP_REFRESH
  End With
End Sub


' Fenster immer im Vordergrund
Public Sub TopWindow(hwnd As Long)
  SetWindowPos hwnd, HWND_TOPMOST, 0, 0, 0, 0, _
    SWP_NOSIZE + SWP_NOMOVE
End Sub

Alles anzeigen

so rufe ich es nun auf:

Code

If mainform.Check2.Enabled = True Then
  ' Fenster immer im Vordergrund anzeigen
  TopWindow Me.hwnd
End If

der code funktioniert wunderbar, allerdings möchte ich es auch wieder umstellen, dass das form nicht mehr immer im vordergrund ist. ich kenn mich leider noch zuwenig aus, als das ich einfach herumprobieren könnte. wahrscheinlich ist es nur ein kleiner "handgriff". vl könnt ihr mir helfen, ich würde mich freuen

mfg SeekeR

SeekeR

so in einem anderem forum haben sie mir geholfen, ich poste hier mal die lösung (im modul):

Code

Private Const HWND_NOTOPMOST = -2


Public Sub UntopWindow(hwnd As Long)


SetWindowPos hwnd, HWND_NOTOPMOST, 0, 0, 0, 0, _
    SWP_NOSIZE + SWP_NOMOVE
End Sub

dann ausführen mit:

Code

UntopWindow me.hwnd

vbtricks

Salut,

bitte das + durch ein Or ersetzen.

Das mag gut gehen, ist aber kein Stil. Das Odern von Flags sollte man sich angewöhnen, sonst bekommt man nämlich Probleme, wenn man mal aus versehen z.B. SWP_NOSIZE + SWP_NOSIZE übergibt.

Stefan

SeekeR

ok danke, den code hab ich eben aus einem anderen forum bekommen, ich werde es umändern. wahrscheinlich hat das den selben grund, wie das mit den message boxen (also zb vbInformation Or vbYesNo)

danke..

mfg SeekeR

vbtricks

Salut,

Zitat von SeekeR

wahrscheinlich hat das den selben grund, wie das mit den message boxen (also zb vbInformation Or vbYesNo)

Hat es. Informatiker verwenden funktionierende Dinge gerne weiter ;).

Stefan

fenster im vordergrund bei vb6 - rückgängig

Tags

Benutzer online in diesem Thema