Mit VB 2005 Txt erstellen und in versciedene Zeilen schreib

Sch4k4l6397

hey,
hätte mal ne Frage... ist es Möglich mit Vb2005 einen Belibigen Text in eine Txt Datei schreiben zu lassen?
Der Text soll dabei in verschidene Zelle eingetragen werden ( mal Zeile 3 ,mal 5 oder mal auch die 10. Zeile)
Gibt es da irgendeinen Befehl das man die Zeile wählen kann die in eine Textdatei geschrieben wird, ich habs bis her so versucht:

Dim objStreamWriter As StreamWriter
objStreamWriter = New StreamWriter("C:\Auswertung_schueler7_Frage7_.txt")
objStreamWriter.WriteLine("Text ")
objStreamWriter.Close()

Aber ich kann so nicht die Zeile wählen...außerdem Soll auf diese Datei mehr mals zugegriffen werden das heißt im ersten Form
wird die Txt erstellt und in Zeile 1 ein Text eingetragen, im nächsten Form soll sie dann wieder geöffnet werden
und in Zeile 2 geschrieben werden
ich hoffe ihr wisst ne Lösung
MFG

vbtricks

Salut,

von Haus aus ist das Schreiben in bestimmte Zeilen meines Wissens nicht möglich. Klar kannst du dir eine entsprechende Funktion schreiben. Allerdings halte ich es nicht für sinnvoll, die ganze Zeit in der Datei rumzuschreiben.
Ich nehme an, du stellst einen Datensatz zusammen. Dafür könntest du doch relativ einfach eine Datenstruktur in einer zentral verfügbaren statischen Klasse anlegen, die du nach Erfassung aller Daten in einem Rutsch in eine Datei schreibst.

Stefan

Tut mir Leid ich bin darin noch ein ziemlicher Anfänger. Es wäre nett wenn du oder ihr eine einfache und funktionierende Lösung ggf. Quellcode reinpostet

MFG

Also es sieht Folgendermaßen aus
Ich will eine Umfrage erstellen je nachdem welcher RadioButton angeklickt wurde wird ein Wert (5 für die beste Anwort 1 für die Negativste Anwort) je Frage gespeichert, so weit so gut nun muss es nur gehen das der Bei jeder Frage wird ne neue Zeile erstellt und dort den Wert
erstellt und dort der Wert eingetragen...
Bei der Ersten Frage wird also die Txt erstellt und dort der Wert eingetragen
Frage 2 (neue Form) soll die Datei wieder öffen und den nächsten Wert eintragen
usw...
bis zu Frage 65
Ich hoffe ihr könnt mir dabei helfen

vbtricks

Salut,

du brauchst eine Form (Form1), darin fünf RadioButtons (RadioButton1, RadioButton2, RadioButton3, RadioButton4, RadioButton5) und einen Button (Button1).

Der Code lässt sich relativ leicht erweitern und speichert das Ergebnis nach Beantwortung der letzten Frage ab.

Code

Imports System.IO


Public Class Form1
    ' Pfad der Ziel-Datei
    Private Const ZielDatei As String = "C:\Auswertung_schueler7_Frage7_.txt"
    ' zu stellende Fragen
    Private ReadOnly Fragen() As String = {"Frage 1", "Frage 2"}
    ' Array fuer die Antworten
    Private Antworten() As Integer
    ' Index der aktuell angezeigten Frage
    ' (beim Start wird aktuelleFrageIndex + 1 angezeigt)
    Private aktuelleFrageIndex As Integer = -1


    ''' <summary>
    ''' Laedt die naechste Frage
    ''' </summary>
    ''' <remarks></remarks>
    Private Sub LadeNaechsteFrage()
        If aktuelleFrageIndex > -1 Then
            ' vorher wurde eine Frage angezeigt, Ergebnis speichern
            Dim Antwort As Integer = 5
            Select Case True
                Case RadioButton1.Checked
                    Antwort = 1
                Case RadioButton2.Checked
                    Antwort = 2
                Case RadioButton3.Checked
                    Antwort = 3
                Case RadioButton4.Checked
                    Antwort = 4
            End Select
            Antworten(aktuelleFrageIndex) = Antwort
        End If


        ' Index erhoehen
        aktuelleFrageIndex += 1


        If aktuelleFrageIndex > Fragen.GetUpperBound(0) Then
            ' keine Fragen mehr, d.h. fertig, speichern
            Dim objStreamWriter As StreamWriter
            objStreamWriter = New StreamWriter(ZielDatei)


            For index As Integer = 0 To Fragen.GetUpperBound(0)
                objStreamWriter.WriteLine(Fragen(index) + ": " _
                    + Antworten(index).ToString())
            Next


            objStreamWriter.Close()


            MessageBox.Show("Ergebnis in Datei gespeichert")
            Me.Close()
        Else
            ' naechste Frage anzeigen
            Label1.Text = Fragen(aktuelleFrageIndex)
            RadioButton3.Checked = True
        End If
    End Sub


    Private Sub Form1_Load(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles MyBase.Load


        ' Antworten-Array auf Groesse des Fragen-Arrays dimensionieren
        ReDim Antworten(Fragen.GetUpperBound(0) + 1)
        ' erste Frage laden
        LadeNaechsteFrage()
    End Sub


    Private Sub Button1_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles Button1.Click


        ' naechste Frage laden
        LadeNaechsteFrage()
    End Sub
End Class

Alles anzeigen

Stefan

Tags